cajon-plugin/build.gradle

plugins {
    id 'java'
    id 'org.jetbrains.intellij' version '0.4.13'
    id 'org.jetbrains.kotlin.jvm' version '1.3.60'
    id 'jacoco'
    id 'com.github.kt3k.coveralls' version '2.8.4'
}

group 'de.platon42'
version '1.7'

repositories {
    mavenCentral()
}

/*
  To run tests in IntelliJ use these VM Options for run configuration 
  -ea -Didea.system.path=build/idea-sandbox/system-test -Didea.config.path=build/idea-sandbox/config-test -Didea.plugins.path=build/idea-sandbox/plugins-test
 */

dependencies {
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    testCompile "org.assertj:assertj-core:3.14.0"
    testCompile "org.assertj:assertj-guava:3.3.0"
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.5.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.5.2'
    testImplementation "org.jetbrains.kotlin:kotlin-test"
//    testImplementation "org.jetbrains.kotlin:kotlin-test-junit"
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
intellij {
    version '2019.2.4'
//    pluginName 'Concise AssertJ Optimizing Nitpicker (Cajon)'
    updateSinceUntilBuild false
    plugins = ['java']
}

patchPluginXml {
    changeNotes """
  <h4>V1.7 (unreleased)</h4>
    <ul>
      <li>Fixed a lapsuus in AssertThatFileExpression also transforming listFiles() with a filter argument.
      <li>Added first version of AssertThatPathExpression for a limited number transformations (more stuff is possible,
          but requires detection and transformation of static Files-methods).
      <li>Added AssertThatComparableExpression for funny compareTo() uses.
    </ul>
  <p>Full changelog available at <a href="https://github.com/chrisly42/cajon-plugin#changelog">Github project site</a>.</p>
"""
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
}

jacoco {
    toolVersion = '0.8.5'
}

jacocoTestReport {
    reports {
        xml.enabled true
        csv.enabled false
    }
}

publishPlugin {
    token intellijPublishToken
}